Landau-Lifshitz, Synge, and Fock pseudotensors are different mathematically and physically

This article delves into the intricacies of pseudotensor analysis, focusing on the derivation of Synge and Fock pseudotensors and their comparison with the Landau-Lifshitz pseudotensor. It underscores the differences in the derivation approaches between Synge and Landau-Lifshitz, particularly highlighting the use of covariant derivatives and the simplification of the Riemann tensor. The author further explores the symmetries of the tensors involved and the implications these have on the derived pseudotensors. The article concludes with a comparative analysis of the canonical forms of the Synge and Landau-Lifshitz pseudotensors, noting the differences in terms and signs.

In a previous post, I showed a detailed derivation of the Landau-Lifshitz pseudotensor in all its forms: metric (canonical), Christoffel, and metric densities. Here, I'll widen the scope of analysis by deriving the closely related Synge and Fock pseudotensors and compare them to the Landau-Lifshitz pseudotensor.

Synge’s stress-energy (pseudo)tensor of the gravitational field

John Lighton Synge (1897-1995)

In space and time, a force we see,
A pseudotensor, wild and free.
Synge's creation, a work of art,
It twists and turns, it plays its part.

In gravity's dance, it holds a key,
A mathematical symmetry.
It tells us how, with great precision,
Matter moves on its own decision.

A hidden force, it may appear,
But in the equations, it is clear.
It guides the stars, and bends the light,
In the universe, it holds a might.

So let us honor Synge's mind,
For the pseudotensor, we shall find,
Is a part of our cosmic tale,
A story yet to be unveiled.

Anonymous

Reading the literature about the Landau-Lifshitz (LL) pseudotensor one cannot help but observe that authors, having encountered the difficulty in deriving the LL pseudotensor, refer to John Lighton Synge's book [2] as a place to get another, simpler derivation of the pseudotensor. This implies that the Synge's pseudotensor in [2] is the same as that of LL in [1]. Some authors, when they talk about the LL pseudotensor, give reference [2] together with [1]. [3][4] Chandrasekhar [6] derives Synge's pseudotensor by the way given in [2] and calls it the Landau-Lifshitz pseudotensor. Synge himself, in footnote on page 252 in [2] writes

We follow here a different approach [than Einstein] presented by Landau and Lifshitz ...

This statement speaks about the same approach but it doesn't mean that the pseudotensors obtained by this approach are the same. On the other hand, Fock writes [5]

A different, but also symmetric set of quantities is used in the book by Landau and Lifshitz, The Classical Theory of Fields

thereby implying that his approach (which is the same as Synge's) derives a pseudotensor that is somewhat different from the Landau-Lifshitz one.

Moreover, Synge's statement about a same approach is fundamentally incorrect because the approaches of Synge and LL are quite different: Synge uses the properties of covariant derivatives to derive his pseudotensor composed of Christoffels coming from the covariant derivatives themselves while LL first eliminate all Christoffels from the the Einstein tensor (transformed down to Riemann tensor), taking only the second metric derivatives and composing from them an antisymmetric tensor whose divergence is identically zero in the locality. Then LL supplement this local pseudotensor with Christoffels (first metric derivatives) taken from the Riemann tensor to make it valid (zero divergence) for the global spacetime. Note that LL do not use covariant derivatives anywhere in their approach.

Synge defines Ricci tensor in a different manner that LL. The latter simplify the Riemann tensor by the first and third indices while Synge simplifies by the second and fourth indices. The Synge's definition differs by sign from LL as mentioned in LL [1] (footnote to formula 92,6) and in Singe [2] (footnote to formula I-(104)). Here, we will recheck Synge's proof, using the Ricci tensor as defined in Synge. Let's define Riemann by Christoffels as in LL91,4:

RiemannLL = MakeRule[{RiemannCD[i, -k, -l, -m], PD[-l][ChristoffelCD[i, -k, -m]] - PD[-m][ChristoffelCD[i, -k, -l]] + ChristoffelCD[i, -n, -l] ChristoffelCD[n, -k, -m] - ChristoffelCD[i, -n, -m] ChristoffelCD[n, -k, -l]}]; (*LL91,4*)
Equal[RiemannCD[i, -k, -l, -m], RiemannCD[i, -k, -l, -m] /. RiemannLL]

$$R_{klm}^i={\mathrm{\Gamma }}_{km,l}^i-{\mathrm{\Gamma }}_{kl,m}^i-{\mathrm{\Gamma }}_{nm}^i{\mathrm{\Gamma }}_{kl}^n+{\mathrm{\Gamma }}_{nl}^i{\mathrm{\Gamma }}_{km}^n$$

We transfer the terms containing the second derivatives on the LHS and the Riemann tensor on the RHS

Equal[%[[2, 3]] + %[[2, 4]], -%[[2, 1]] - %[[2, 2]] + %[[1]]]

$${\mathrm{\Gamma }}_{km,l}^i-{\mathrm{\Gamma }}_{kl,m}^i=R_{klm}^i-{\mathrm{\Gamma }}_{nl}^i{\mathrm{\Gamma }}_{km}^n+{\mathrm{\Gamma }}_{nm}^i{\mathrm{\Gamma }}_{kl}^n$$

For the Ricci tensor we make a rule exactly as in LL92,7

RicciLL = MakeRule[{RicciCD[-i, -k], PD[-l][ChristoffelCD[l, -i, -k]] - PD[-k][ChristoffelCD[l, -i, -l]] + ChristoffelCD[l, -i, -k] ChristoffelCD[m, -l, -m] - ChristoffelCD[m, -i, -l] ChristoffelCD[l, -k, -m]}]; (*LL92,7*)
Equal[RicciCD[-i, -k], RicciCD[-i, -k] /. RicciLL];
Equal[%[[2, 3]] + %[[2, 4]], -%[[2, 1]] - %[[2, 2]] + %[[1]]]

$${\mathrm{\Gamma }}_{ik,l}^l-{\mathrm{\Gamma }}_{il,k}^l=R_{ik}-{\mathrm{\Gamma }}_{ik}^l{\mathrm{\Gamma }}_{lm}^m+{\mathrm{\Gamma }}_{km}^l{\mathrm{\Gamma }}_{il}^m$$

Compare these with the Synge's formulae VI-(151) on page 254:

${\mathrm{\Gamma }}_{kl,m}^i-{\mathrm{\Gamma }}_{km,l}^i=R_{kml}^i-{\mathrm{\Gamma }}_{nm}^i{\mathrm{\Gamma }}_{kl}^n+{\mathrm{\Gamma }}_{nl}^i{\mathrm{\Gamma }}_{km}^n$
${\mathrm{\Gamma }}_{lk,i}^l-{\mathrm{\Gamma }}_{ik,l}^l=R_{ik}-{\mathrm{\Gamma }}_{im}^l{\mathrm{\Gamma }}_{kl}^m+{\mathrm{\Gamma }}_{ik}^l{\mathrm{\Gamma }}_{lm}^m$

It is easy to see several differences in indices, some of which are sign changes, and others are due to reshuffling of the antisymmetric indices l and m which amounts to the same.

Let’s reiterate the formula for $T^{ik}$ given in the previous post and look at it from somewhat different angle

$(-g)T^{ik}=\frac{c^4}{16\pi k}{[(-g)(g^{ik}{g}^{lm}-g^{il}{g}^{km})]}_{,m,l}$

The expression in the brackets can be replaced with a tensor

$U^{iklm}=(-g)(g^{ik}{g}^{lm}-g^{il}{g}^{km})$

The order of indexes in $U^{iklm}$ is not arbitrary but so chosen that $U^{iklm}$ has the same symmetries as the Riemann tensor $R^{iklm}$ namely antisymmetric for each index pairs ik and lm and symmetric for permutation of these pairs.

DefTensor[U[i, k, l, m], M4, RiemannSymmetric[{1, 2, 3, 4}]];
U1 = MakeRule[{U[i, k, l, m], Detmetricg[] (metricg[i, k] metricg[l, m] - metricg[i, l] metricg[k,m])}];

** DefTensor: Defining tensor U[i,k,l,m].

$U^{iklm}$ corresponds to ${\lambda }^{iklm}$ from LL96,3 but without the constant $\frac{c^4}{16\pi k}$

Next, Synge observes that if $U^{iklm}$ has the same symmetries as the Riemann tensor $R^{iklm}$ then its third derivatives by lmk should be zero. Let’s check

ToCanonical[PD[-k][PD[-l][PD[-m][U[i, l, k, m]/.U1]]]] == 0

true

and the covariant derivative of $U^{iklm}$ vanish as well

ToCanonical[CD[-n][U[i, k, l, m]./U1]] == 0

true

Let's develop the CD by an arbitrary index n to Christoffels as is its usual definition, not forgetting that this whole expression is zero. We will put the metric determinant on hold so that the expression will not be processed so as to nullify the covariant derivative of the determinant

SetOptions[ToCanonical, UseMetricOnVBundle -> None];
CDbyN = CD[-n][1/Hold[Detmetricg[]] U[i, k, l, m]] // CovDToChristoffel

$$-\frac{U^{iklm}{g}_{,n}}{g^2}+\frac{{\mathrm{\Gamma }}_{ns}^m{U}^{ikls}+{\mathrm{\Gamma }}_{nr}^l{U}^{ikrm}+{\mathrm{\Gamma }}_{nq}^k{U}^{iqlm}+{\mathrm{\Gamma }}_{np}^i{U}^{pklm}+U_{,n}^{iklm}}{g}$$

Since the LHS is zero, we can multiply this expression by g to get rid of the denominator

Uiklmn = Hold[Detmetricg[]] CDbyN // Expand

$${\mathrm{\Gamma }}_{np}^m{U}^{iklp}+{\mathrm{\Gamma }}_{np}^l{U}^{ikpm}+{\mathrm{\Gamma }}_{np}^k{U}^{iplm}+{\mathrm{\Gamma }}_{np}^i{U}^{pklm}-\frac{U^{iklm}{g}_{,n}}{g}+U_{,n}^{iklm}$$

According to LL86,5 $\frac{g_{,n}}{g}=2{\mathrm{\Gamma }}_{np}^p$ and substituting it and transferring $U_{,n}^{iklm}$ on the other side of the equation, we obtain Synge's VI-(153)

Uiklmn /. {PD[-n][Hold[Detmetricg[]]]/Hold[Detmetricg[]] -> 2 ChristoffelCD[p, -n, -p]}

$$-2{\mathrm{\Gamma }}_{np}^p{U}^{iklm}+{\mathrm{\Gamma }}_{np}^m{U}^{iklp}+{\mathrm{\Gamma }}_{np}^l{U}^{ikpm}+{\mathrm{\Gamma }}_{np}^k{U}^{iplm}+{\mathrm{\Gamma }}_{np}^i{U}^{pklm}+U_{,n}^{iklm}$$

Uiklmn = -(%[[1]] + %[[2]] + %[[3]] + %[[4]] + %[[5]])

$$2{\mathrm{\Gamma }}_{np}^p{U}^{iklm}-{\mathrm{\Gamma }}_{np}^m{U}^{iklp}-{\mathrm{\Gamma }}_{np}^l{U}^{ikpm}-{\mathrm{\Gamma }}_{np}^k{U}^{iplm}-{\mathrm{\Gamma }}_{np}^i{U}^{pklm}$$

To get the covariant derivative by k, simply substitute n by k

Uiklmn /. {n -> k}
Uiklmk = %/.{p -> n}

$$2{\mathrm{\Gamma }}_{kn}^n{U}^{iklm}-{\mathrm{\Gamma }}_{kn}^m{U}^{ikln}-{\mathrm{\Gamma }}_{kn}^l{U}^{iknm}-{\mathrm{\Gamma }}_{kn}^k{U}^{inlm}-{\mathrm{\Gamma }}_{kn}^i{U}^{nklm}$$

Canonicalization reduces the terms from 5 to 3

UiklmkCan = Uiklmk // ToCanonical

$$-{\mathrm{\Gamma }}_{kn}^m{U}^{ikln}+{\mathrm{\Gamma }}_{kn}^l{U}^{ikmn}+{\mathrm{\Gamma }}_{kn}^k{U}^{inlm}$$

Since canonicalization is not transparent, let me explain what is going on. In the fourth term, we exchange the dummy indices k and n. This does not change sign because k and n are symmetric in ${\mathrm{\Gamma }}_{kn}^k$.

${\mathrm{\Gamma }}_{kn}^k{U}^{inlm}={\mathrm{\Gamma }}_{nk}^n{U}^{iklm}={\mathrm{\Gamma }}_{kn}^n{U}^{iklm}$

Then the fourth term cancels with the first term to give ${\mathrm{\Gamma }}_{kn}^n{U}^{iklm}$. In the last term, we see that k and n are symmetric in ${\mathrm{\Gamma }}_{kn}^i$ but antisymmetric in $U^{nklm}$. So, if we symmetrize ${\mathrm{\Gamma }}_{kn}^i{U}^{nklm}$ by n and k

Symmetrize[ChristoffelCD[i, -k, -n] U[n, k, l, m], {n, k}]

$$\frac{1}{2}({\mathrm{\Gamma }}_{kn}^i{U}^{knlm}+{\mathrm{\Gamma }}_{kn}^i{U}^{nklm})$$

But $U^{nklm}=-U^{knlm}$ and the above expression becomes zero

ToCanonical[Symmetrize[ChristoffelCD[i, -k, -n] U[n, k, l, m], {n, k}]] == 0

true

It remains to do some cosmetic changes to the canonicalized Uiklmk: exchange k and n in the last term which does not change sign

${\mathrm{\Gamma }}_{kn}^k{U}^{inlm}={\mathrm{\Gamma }}_{nk}^n{U}^{iklm}={\mathrm{\Gamma }}_{kn}^n{U}^{iklm}$

and exchange m and n in the second term, which changes sign

${\mathrm{\Gamma }}_{kn}^l{U}^{ikmn}=-{\mathrm{\Gamma }}_{kn}^l{U}^{iknm}$

The expression for Uiklmk becomes

${\mathrm{\Gamma }}_{kn}^n{U}^{iklm}-{\mathrm{\Gamma }}_{kn}^l{U}^{iknm}-{\mathrm{\Gamma }}_{kn}^m{U}^{ikln}$

the same as Singe's VI-(154).

An ordinary differentiation of the above by m gives

Uiklmkm = PD[-m][UiklmkCan]

$$U^{inlm}{\mathrm{\Gamma }}_{kn,m}^k-U^{ikmn}{\mathrm{\Gamma }}_{kn,m}^l-U^{ikln}{\mathrm{\Gamma }}_{kn,m}^m-{\mathrm{\Gamma }}_{kn}^m{U}_{,m}^{ikln}-{\mathrm{\Gamma }}_{kn}^l{U}_{,m}^{ikmn}+{\mathrm{\Gamma }}_{kn}^k{U}_{,m}^{inlm}$$

Note that the second derivatives of the metric are contained in the first three terms, while terms 4,5,6 contain only first derivatives. We will separate second and first derivatives in the tensors Ail and Bil, respectively. As we will not use Ail and Bil for tensor operations, it suffice to treat them just as ordinary variables. We will also do a simplification of Ail, which factors common multipliers

Ail = Uiklmkm[[1 ;; 3]] // Simplification
Bil = Uiklmkm[[4 ;; 6]]

$$U^{imln}(-{\mathrm{\Gamma }}_{mn,k}^k+{\mathrm{\Gamma }}_{km,n}^k)-U^{ikmn}{\mathrm{\Gamma }}_{km,n}^l$$ $$-{\mathrm{\Gamma }}_{kn}^m{U}_{,m}^{ikln}+{\mathrm{\Gamma }}_{kn}^l{U}_{,m}^{ikmn}+{\mathrm{\Gamma }}_{kn}^k{U}_{,m}^{inlm}$$

Here, Synge's idea is to substitute the expression in parentheses in Ail, containing second metric derivatives with the RHS of the equation containing the Ricci tensor plus first metric derivatives. Let's exchange the dummy indices: $k\to m\to n$:

$U^{imln}(-{\mathrm{\Gamma }}_{mn,k}^k+{\mathrm{\Gamma }}_{km,n}^k)=U^{ikln}(-{\mathrm{\Gamma }}_{kn,m}^m+{\mathrm{\Gamma }}_{km,n}^m)=U^{iklm}({\mathrm{\Gamma }}_{kn,m}^n-{\mathrm{\Gamma }}_{km,n}^n)$

The third term in Ail is transformed in

$-U^{ikmn}{\mathrm{\Gamma }}_{km,n}^l=U^{iknm}{\mathrm{\Gamma }}_{kn,m}^l$

and antisymmetrized by the lower n and m

Antisymmetrize[ U[i, k, n, m] PD[-n][ChristoffelCD[l, -k, -m]], {-n, -m}]

$$\frac{1}{2}{U}^{iknm}({\mathrm{\Gamma }}_{km,n}^l-{\mathrm{\Gamma }}_{kn,m}^l)$$

Thus, for Ail we arrive to Singe's VI-(157)

$A^{il}=U^{iklm}({\mathrm{\Gamma }}_{kn,m}^n-{\mathrm{\Gamma }}_{km,n}^n)+\frac{1}{2}{U}^{iknm}({\mathrm{\Gamma }}_{km,n}^l-{\mathrm{\Gamma }}_{kn,m}^l)$

Now substitute the terms in the first parentheses with the RHS of the expression for the Ricci tensor as defined by Synge:

$U^{iklm}({\mathrm{\Gamma }}_{kn,m}^n-{\mathrm{\Gamma }}_{km,n}^n)=U^{iklm}{R}_{km}+U^{iklm}({\mathrm{\Gamma }}_{km}^n{\mathrm{\Gamma }}_{np}^p-{\mathrm{\Gamma }}_{mp}^n{\mathrm{\Gamma }}_{kp}^p)$

The terms in the second parentheses are substituted with the RHS of the expression for the Riemann tensor as defined by Synge:

$\frac{1}{2}{U}^{iknm}({\mathrm{\Gamma }}_{km,n}^l-{\mathrm{\Gamma }}_{kn,m}^l)=\frac{1}{2}{U}^{iknm}{R}_{knm}^l+\frac{1}{2}{U}^{iknm}({\mathrm{\Gamma }}_{kn}^p{\mathrm{\Gamma }}_{mp}^l-{\mathrm{\Gamma }}_{km}^p{\mathrm{\Gamma }}_{np}^l)$

or, by changing the indices n and m in the second term

$$$\begin{array}{c}\frac{1}{2}{U}^{iknm}({\mathrm{\Gamma }}_{kn}^p{\mathrm{\Gamma }}_{pm}^l-{\mathrm{\Gamma }}_{km}^p{\mathrm{\Gamma }}_{np}^l)=\frac{1}{2}{U}^{iknm}{\mathrm{\Gamma }}_{kn}^p{\mathrm{\Gamma }}_{pm}^l-\frac{1}{2}{U}^{iknm}{\mathrm{\Gamma }}_{km}^p{\mathrm{\Gamma }}_{np}^l=\hfill \\ \hfill \frac{1}{2}{U}^{iknm}{\mathrm{\Gamma }}_{kn}^p{\mathrm{\Gamma }}_{mp}^l+\frac{1}{2}{U}^{iknm}{\mathrm{\Gamma }}_{kn}^p{\mathrm{\Gamma }}_{mp}^l=U^{iknm}{\mathrm{\Gamma }}_{kn}^p{\mathrm{\Gamma }}_{mp}^l\end{array}$$$

Substituting $U^{iklm}$ and $U^{iknm}$ with their equivalents in metric tensors and taking into account the sign difference of the Riemann tensor between Singe [2] and LL [1]

U[i, k, l, m] RicciCD[-k, -m] /. U1 // ToCanonical // ContractMetric
- U[i, k, n, m] RiemannCD[l, -k, -n, -m] /. U1 // ToCanonical // ContractMetric

$$-g{R}^{il}+g{g}^{il}R$$ $$-g{R}^{il}$$

Summing these terms in Ail, we obtain

$A^{il}=-g(2R^{il}-g^{il}R)+U^{iklm}({\mathrm{\Gamma }}_{km}^n{\mathrm{\Gamma }}_{np}^p-{\mathrm{\Gamma }}_{mp}^n{\mathrm{\Gamma }}_{kp}^p)+U^{iknm}{\mathrm{\Gamma }}_{kn}^p{\mathrm{\Gamma }}_{mp}^l$

$-g(2R^{il}-g^{il}R)=-2g{G}^{il}$ where $G^{il}$ is the Einstein tensor

So, for $U_{,km}^{iklm}$ we have VI-(160)

$U_{,km}^{iklm}=-2g{G}^{il}+2V^{il}$

where $2V^{il}$ is VI-(161)

$2V^{il}=U^{iklm}({\mathrm{\Gamma }}_{km}^n{\mathrm{\Gamma }}_{np}^p-{\mathrm{\Gamma }}_{mp}^n{\mathrm{\Gamma }}_{kp}^p)+U^{iknm}{\mathrm{\Gamma }}_{kn}^p{\mathrm{\Gamma }}_{mp}^l+B^{il}$

It remains to substitute Bil, expressed in terms of $U_n^{iklm}$ with the expression Synge VI-(153) obtained above. For this purpose we shall make a rule to be sure that the indices are handled properly.

rule1 = MakeRule[{PD[-n][U[i, k, l, m]], 2*ChristoffelCD[p, -n, -p]*U[i, k, l, m] - ChristoffelCD[m, -n, -p]*U[i, k, l, p] - ChristoffelCD[l, -n, -p]*U[i, k, p, m] - ChristoffelCD[k, -n, -p]*U[i, p, l, m] - ChristoffelCD[i, -n, -p]*U[p, k, l, m]}];
Bik /. rule1 // ToCanonical

$$\begin{array}{c}-{\mathrm{\Gamma }}_{km}^l{\mathrm{\Gamma }}_{np}^n{U}^{ikmp}+{\mathrm{\Gamma }}_{km}^k{\mathrm{\Gamma }}_{np}^n{U}^{imlp}+2{\mathrm{\Gamma }}_{mn}^k{\mathrm{\Gamma }}_{kp}^m{U}^{inlp}-3{\mathrm{\Gamma }}_{km}^k{\mathrm{\Gamma }}_{np}^m{U}^{inlp}+2{\mathrm{\Gamma }}_{np}^k{\mathrm{\Gamma }}_{km}^l{U}^{inmp}-\hfill \\ \hfill {\mathrm{\Gamma }}_{km}^i{\mathrm{\Gamma }}_{np}^l{U}^{knmp}-{\mathrm{\Gamma }}_{km}^i{\mathrm{\Gamma }}_{np}^n{U}^{lkmp}+{\mathrm{\Gamma }}_{km}^i{\mathrm{\Gamma }}_{np}^k{U}^{lnmp}\end{array}$$

To these terms we should add the additional $U^{iklm}$ terms from I-(161)

% + U[i, k, l, m] (ChristoffelCD[n, -m, -k]*ChristoffelCD[p, -n, -p] - ChristoffelCD[n, -m, -p]*ChristoffelCD[p, -k, -n]) + U[i, k, n, m]*ChristoffelCD[p, -k, -n]*ChristoffelCD[l, -p, -m]
SyngeAutomatic = % // ToCanonical

$$\begin{array}{c}-{\mathrm{\Gamma }}_{km}^l{\mathrm{\Gamma }}_{np}^n{U}^{ikmp}+{\mathrm{\Gamma }}_{km}^k{\mathrm{\Gamma }}_{np}^n{U}^{imlp}+{\mathrm{\Gamma }}_{mn}^k{\mathrm{\Gamma }}_{kp}^m{U}^{inlp}-2{\mathrm{\Gamma }}_{km}^k{\mathrm{\Gamma }}_{np}^m{U}^{inlp}+\hfill \\ \hfill {\mathrm{\Gamma }}_{np}^k{\mathrm{\Gamma }}_{km}^l{U}^{inmp}-{\mathrm{\Gamma }}_{km}^i{\mathrm{\Gamma }}_{np}^l{U}^{knmp}-{\mathrm{\Gamma }}_{km}^i{\mathrm{\Gamma }}_{np}^n{U}^{lkmp}+{\mathrm{\Gamma }}_{km}^i{\mathrm{\Gamma }}_{np}^k{U}^{lnmp}\end{array}$$

This is the Synge VI-(162) in an expanded form. We have to check it to be sure by manual entering and comparing.

U[i, k, l, m] (ChristoffelCD[n, -n, -k] ChristoffelCD[p, -p, -m] + ChristoffelCD[n, -p, -k] ChristoffelCD[p, -n, -m] - 2 ChristoffelCD[n, -k, -m] ChristoffelCD[p, -n, -p]) + U[i, k, m, n] (-ChristoffelCD[l, -k, -m] ChristoffelCD[p, -p, -n] - ChristoffelCD[p, -k, -m] ChristoffelCD[l, -p, -n]) + U[l, k, m, n] (-ChristoffelCD[i, -k, -m] ChristoffelCD[p, -p, -n] - ChristoffelCD[p, -k, -m] ChristoffelCD[i, -p, -n]) + U[k, m, n, p] ChristoffelCD[i, -k, -p] ChristoffelCD[l, -m, -n]
SyngeManual = % // ToCanonical

$$\begin{array}{c}-{\mathrm{\Gamma }}_{km}^l{\mathrm{\Gamma }}_{np}^n{U}^{ikmp}+{\mathrm{\Gamma }}_{km}^k{\mathrm{\Gamma }}_{np}^n{U}^{imlp}+{\mathrm{\Gamma }}_{mn}^k{\mathrm{\Gamma }}_{kp}^m{U}^{inlp}-2{\mathrm{\Gamma }}_{km}^k{\mathrm{\Gamma }}_{np}^m{U}^{inlp}+\hfill \\ \hfill {\mathrm{\Gamma }}_{np}^k{\mathrm{\Gamma }}_{km}^l{U}^{inmp}-{\mathrm{\Gamma }}_{km}^i{\mathrm{\Gamma }}_{np}^l{U}^{knmp}-{\mathrm{\Gamma }}_{km}^i{\mathrm{\Gamma }}_{np}^n{U}^{lkmp}+{\mathrm{\Gamma }}_{km}^i{\mathrm{\Gamma }}_{np}^k{U}^{lnmp}\end{array}$$

SyngeAutomatic - SyngeManual == 0

true

The final result from our calculation is exactly the same as in Synge's book. Let's develop the $U^{iklm}$ terms to metrics to compare the Synge pseudotensor with the LL one.

SyngeAutomatic /. U1 // ToCanonical;
SyngeInMetrics = %/Detmetricg[] // ToCanonical

$$\begin{array}{c}{\mathrm{\Gamma }}_{km}^k{\mathrm{\Gamma }}_{np}^n{g}^{im}{g}^{lp}+{\mathrm{\Gamma }}_{mn}^k{\mathrm{\Gamma }}_{kp}^m{g}^{in}{g}^{lp}-2{\mathrm{\Gamma }}_{km}^k{\mathrm{\Gamma }}_{np}^m{g}^{in}{g}^{lp}-{\mathrm{\Gamma }}_{km}^k{\mathrm{\Gamma }}_{np}^n{g}^{il}{g}^{mp}+{\mathrm{\Gamma }}_{np}^k{\mathrm{\Gamma }}_{km}^l{g}^{in}{g}^{mp}-\hfill \\ \hfill {\mathrm{\Gamma }}_{km}^i{\mathrm{\Gamma }}_{np}^l{g}^{kn}{g}^{mp}+{\mathrm{\Gamma }}_{km}^i{\mathrm{\Gamma }}_{np}^k{g}^{ln}{g}^{mp}-{\mathrm{\Gamma }}_{mn}^k{\mathrm{\Gamma }}_{kp}^m{g}^{il}{g}^{np}+2{\mathrm{\Gamma }}_{km}^k{\mathrm{\Gamma }}_{np}^m{g}^{il}{g}^{np}-{\mathrm{\Gamma }}_{np}^k{\mathrm{\Gamma }}_{km}^l{g}^{im}{g}^{np}+{\mathrm{\Gamma }}_{km}^i{\mathrm{\Gamma }}_{np}^l{g}^{km}{g}^{np}-{\mathrm{\Gamma }}_{km}^i{\mathrm{\Gamma }}_{np}^k{g}^{lm}{g}^{np}\end{array}$$

Not a good sign in terms of comparison. From 16 potential terms in Synge's pseudotensor, canonicalization leaves only 12. Canonicalization of the LL pseudotensor leaves all 16 terms. There is no point in futher direct comparison. Let's try to see where the difference lies. It was said above that Synge's $U^{iklm}$ is an analogue of the LL ${\lambda }^{iklm}$. In Synge, e.g. VI-(160), it is seen that the basis for the derivation is $U^{iklm}$ differentiated by its second and fourth indices, $U_{,k,m}^{iklm}$, leaving free the first and third indices. In LL, ${\lambda }^{iklm}$ is differentiated by the third and fourth indices, ${\lambda }_{,l,m}^{iklm}$, leaving free the first and second indices. See, e.g. LL96,2 and LL96,5. It's very possible this is the cause for the difference.

Let us try to derive the Synge's tensor with differentiations by the third and fourth indices.

Uiklmn /. {n -> l};
Uiklml = % /. {p -> n}

$$2{\mathrm{\Gamma }}_{ln}^n{U}^{iklm}-{\mathrm{\Gamma }}_{ln}^m{U}^{ikln}-{\mathrm{\Gamma }}^l{}_{ln}{U}^{iknm}-{\mathrm{\Gamma }}_{ln}^k{U}^{inlm}-{\mathrm{\Gamma }}_{ln}^i{U}^{nklm}$$

UiklmlCan = Uiklml // ToCanonical

$$-{\mathrm{\Gamma }}_{ln}^l{U}^{ikmn}+{\mathrm{\Gamma }}_{ln}^k{U}^{ilmn}-{\mathrm{\Gamma }}_{ln}^i{U}^{klmn}$$

Uiklmlm = PD[-m][UiklmlCan]

$$-U^{klmn}{\mathrm{\Gamma }}_{ln,m}^i+U^{ilmn}{\mathrm{\Gamma }}_{ln,m}^k-U^{ikmn}{\mathrm{\Gamma }}_{ln,m}^l-{\mathrm{\Gamma }}_{ln}^l{U}_{,m}^{ikmn}+{\mathrm{\Gamma }}_{ln}^k{U}_{,m}^{ilmn}-{\mathrm{\Gamma }}_{ln}^i{U}_{,m}^{klmn}$$

Here, the terms with the second derivatives constituting the Aik tensor can no longer be arranged in Ricci tensor. This makes impossible to continue derivation of the Synge's pseudotensor.

As another check, let us see if the canonical pseudotensor derived from Synge's pseudotensor is the same as the LL canonical pseudotensor.

SyngeInMetrics/2 // ChristoffelToGradMetric // ToCanonical

$$\begin{array}{c}-\frac{1}{4}{g}^{ik}{g}^{lm}{g}^{np}{g}^{qr}{g}_{nq}{}_{,k}{g}_{pr}{}_{,m}+\frac{1}{4}{g}^{ik}{g}^{lm}{g}^{np}{g}^{qr}{g}_{np}{}_{,k}{g}_{qr}{}_{,m}-\frac{1}{4}{g}^{ik}{g}^{lm}{g}^{np}{g}^{qr}{g}_{qr}{}_{,m}{g}_{kn}{}_{,p}-\frac{1}{4}{g}^{ik}{g}^{lm}{g}^{np}{g}^{qr}{g}_{qr}{}_{,k}{g}_{mn}{}_{,p}-\hfill \\ \frac{1}{4}{g}^{ik}{g}^{lm}{g}^{np}{g}^{qr}{g}_{mn}{}_{,k}{g}_{qr}{}_{,p}-\frac{1}{4}{g}^{ik}{g}^{lm}{g}^{np}{g}^{qr}{g}_{kn}{}_{,m}{g}_{qr}{}_{,p}-\frac{3}{8}{g}^{il}{g}^{km}{g}^{np}{g}^{qr}{g}_{km}{}_{,n}{g}_{qr}{}_{,p}+\frac{1}{2}{g}^{ik}{g}^{lm}{g}^{np}{g}^{qr}{g}_{km}{}_{,n}{g}_{qr}{}_{,p}+\\ \frac{1}{2}{g}^{ik}{g}^{lm}{g}^{np}{g}^{qr}{g}_{pr}{}_{,m}{g}_{kn}{}_{,q}-\frac{1}{4}{g}^{il}{g}^{km}{g}^{np}{g}^{qr}{g}_{mr}{}_{,p}{g}_{kn}{}_{,q}+\frac{1}{2}{g}^{ik}{g}^{lm}{g}^{np}{g}^{qr}{g}_{pr}{}_{,k}{g}_{mn}{}_{,q}+\frac{1}{8}{g}^{il}{g}^{km}{g}^{np}{g}^{qr}{g}_{kn}{}_{,q}{g}_{mp}{}_{,r}-\\ \hfill \frac{1}{2}{g}^{ik}{g}^{lm}{g}^{np}{g}^{qr}{g}_{kn}{}_{,q}{g}_{mp}{}_{,r}+\frac{1}{2}{g}^{ik}{g}^{lm}{g}^{np}{g}^{qr}{g}_{kn}{}_{,p}{g}_{mq}{}_{,r}+\frac{1}{2}{g}^{il}{g}^{km}{g}^{np}{g}^{qr}{g}_{km}{}_{,n}{g}_{pq}{}_{,r}-\frac{1}{2}{g}^{ik}{g}^{lm}{g}^{np}{g}^{qr}{g}_{km}{}_{,n}{g}_{pq}{}_{,r}\end{array}$$

Surprise, the canonical Synge pseudotensor has 16 terms, the same as the canonical LL pseudotensor. Now if we immediately try to subtract the above from the canonical LL pseudotensor and canonicalize, we will be thrown an error in validation because of inhomogeneous indices. Indeed, the free indices of the above expression are i, l while in LL canonical they are i, k. Therefore, we must first make the free indices in the two expressions the same (i, k) and then compare by subtracting.

ChangeFreeIndices[%, {i, k}];
(LLCanonical - %) // ToCanonical

$$\begin{array}{c}\frac{1}{2}{g}^{il}{g}^{km}{g}^{np}{g}^{qr}{g}_{nq}{}_{,l}{g}_{pr}{}_{,m}-\frac{3}{4}{g}^{il}{g}^{km}{g}^{np}{g}^{qr}{g}_{np}{}_{,l}{g}_{qr}{}_{,m}+\frac{3}{4}{g}^{il}{g}^{km}{g}^{np}{g}^{qr}{g}_{qr}{}_{,m}{g}_{ln}{}_{,p}+\frac{3}{4}{g}^{il}{g}^{km}{g}^{np}{g}^{qr}{g}_{qr}{}_{,l}{g}_{mn}{}_{,p}+\hfill \\ \frac{1}{2}{g}^{il}{g}^{km}{g}^{np}{g}^{qr}{g}_{mn}{}_{,l}{g}_{qr}{}_{,p}+\frac{1}{2}{g}^{il}{g}^{km}{g}^{np}{g}^{qr}{g}_{ln}{}_{,m}{g}_{qr}{}_{,p}-\frac{5}{4}{g}^{il}{g}^{km}{g}^{np}{g}^{qr}{g}_{lm}{}_{,n}{g}_{qr}{}_{,p}+\frac{3}{4}{g}^{ik}{g}^{lm}{g}^{np}{g}^{qr}{g}_{lm}{}_{,n}{g}_{qr}{}_{,p}-\\ g^{il}{g}^{km}{g}^{np}{g}^{qr}{g}_{pr}{}_{,m}{g}_{ln}{}_{,q}+\frac{1}{2}{g}^{ik}{g}^{lm}{g}^{np}{g}^{qr}{g}_{mr}{}_{,p}{g}_{ln}{}_{,q}-g^{il}{g}^{km}{g}^{np}{g}^{qr}{g}_{pr}{}_{,l}{g}_{mn}{}_{,q}+g^{il}{g}^{km}{g}^{np}{g}^{qr}{g}_{ln}{}_{,q}{g}_{mp}{}_{,r}-\\ \hfill \frac{1}{4}{g}^{ik}{g}^{lm}{g}^{np}{g}^{qr}{g}_{ln}{}_{,q}{g}_{mp}{}_{,r}-g^{il}{g}^{km}{g}^{np}{g}^{qr}{g}_{ln}{}_{,p}{g}_{mq}{}_{,r}+g^{il}{g}^{km}{g}^{np}{g}^{qr}{g}_{lm}{}_{,n}{g}_{pq}{}_{,r}-g^{ik}{g}^{lm}{g}^{np}{g}^{qr}{g}_{lm}{}_{,n}{g}_{pq}{}_{,r}\end{array}$$

We see that subtracting the 2 pseudotensors tends to increase their numerical coefficients. This means that on the whole they are with somewhat opposite sign. So let's add them.

(LLCanonical + %) // ToCanonical

$$-\frac{1}{4}{g}^{il}{g}^{km}{g}^{np}{g}^{qr}{g}_{np}{}_{,l}{g}_{qr}{}_{,m}+\frac{1}{4}{g}^{il}{g}^{km}{g}^{np}{g}^{qr}{g}_{qr}{}_{,m}{g}_{ln}{}_{,p}+\frac{1}{4}{g}^{il}{g}^{km}{g}^{np}{g}^{qr}{g}_{qr}{}_{,l}{g}_{mn}{}_{,p}-\frac{1}{4}{g}^{il}{g}^{km}{g}^{np}{g}^{qr}{g}_{lm}{}_{,n}{g}_{qr}{}_{,p}$$

We can conclude from here that the Synge pseudotensor has a sign opposite to that of LL pseudotensor and the sum of the two pseudotensors leaves a small 4-terms residue.

Finally, let's see if the Synge pseudotensor is symmetric for the free indices i and l which is equivalent to antisymmetrizing it and equating it to 0.

ToCanonical[Antisymmetrize[SyngeAutomatic, {i, l}]] == 0

true

This shows that Synge's pseudotensor is symmetric.

---

1.The classical theory of fields by Lev Davidovich Landau and Evgeniy Mikhaylovich Lifshitz.Translated by Morton Hamermesh.Edition : 4, illustrated, revised.Published by Butterworth - Heinemann, 1975. ISBN 0750627689, 9780750627689. 402 pages [Russian original: Л. Д. Ландау и Е. М. Лифшиц, Теория поля, 8-е издание, том II из десятитомного труда Теоретическая физика, изд. Физматлит, Москва, 2003, 536 с. ISBN 5-9221-0056-4]

2. J. L. Synge. Relativity : The General Theory, 1960, Ch.VI, Sect.7

3. J. H. Caltenco, J. I. López-Bonilla, R. Peña-Rivero and J. Rivera-Rebolledo. Landau-Lifshitz energy-momentum pseudotensor for metrics with spherical symmetry. Proc. Pakistan Acad. Sci. 42(4):261-264.2005

4. G. Bahadur Thapa, A. Hernández-Galeana, J. López-Bonilla. Continuity equations in curved spaces. World Scientific News, 105 (2018) 197-203, EISSN 2392-2192

5. Vladimir Fock. The Theory of Space, Time, and Gravitation, 2nd revised edition, Pergamon Press, 1964 [Russian original: В. А. Фок, Теория пространства, времени и тяготения, Издание второе, дополненное, Государственное издательство физико-математической литературы, Москва, 1961]

6. Subrahmanyan Chandrasekhar and Valeria Ferrari. The Einstein pseudo-tensor and the flux integral for perturbed static spacetimes. In: Selected papers, Volume 7. The Non-radial Oscillations of Stars in General Relativity and Other Writings, The University of Chicago Press, 1997, ISBN 0-226-10103-7

7. A. S. Eddington. The Mathematical Theory of Relativity. 2nd Edition. Cambridge University Press. 1930, London

8. Leonovich A.A., Vyblyi Yu. P. The Classical Energy–Momentum Problem and Fock Tensor in Relativistic Theory of Gravitation. Nonlinear Phenomena in Complex Systems, vol. 21, no. 4 (2018), pp. 406 - 410